GSAS/iRODSDescriptorProcessing: geniObject.xsl

<?xml version="1.0"?>
<xsl:stylesheet xmlns:g="http://geni.net/schema" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" indent="yes" encoding="UTF-8"/>
<xsl:strip-space elements="*" />


<!-- root element -->
<xsl:template match="/*" priority="1">
        <metadata>
        <xsl:apply-templates>
                <xsl:with-param name="path" select="name()"/>
        </xsl:apply-templates>
        </metadata>
</xsl:template>


<!-- non leaf node -->
<xsl:template match="*[*]">
        <xsl:param name="path"/>        
        <xsl:apply-templates>
                <xsl:with-param name="path" select="concat($path,'_',name())"/>
        </xsl:apply-templates>
</xsl:template>


<!-- leaf node -->
<xsl:template match="*[not(*)]">
        <xsl:param name="path"/>
        <xsl:element name="AVU">
                <xsl:element name="Attribute">
                        <xsl:value-of select="concat($path,'_',name())"/>
                </xsl:element>
                <xsl:element name="Value">
                        <xsl:apply-templates/>
                </xsl:element>
        </xsl:element>
</xsl:template>


</xsl:stylesheet>