GSAS/iRODSDescriptorProcessing: geniMetadataExtractExple1.r

main {
        # A few checks to get meaningful error messages
        dataObjExists(*geniXmlObjPath);
        dataObjExists(*xsltObjPath);
        hasExtension(*geniXmlObjPath,"xml");
        hasExtension(*xsltObjPath,"xsl");

        # Apply stylesheet
        msiXsltApply(*xsltObjPath, *geniXmlObjPath, *buffer);

        # Generate path of formatted metadata object
        msiSplitPath(*geniXmlObjPath, *collection, *filename);
        *metadataObjPath=*collection++"/"++trimr(*filename,".")++"_formatted.xml";

        # Create and write to metadata object
        msiDataObjCreate(*metadataObjPath, "forceFlag=", *D_FD);
        msiDataObjWrite(*D_FD, *buffer, *W_len);
        msiDataObjClose(*D_FD, *status);

        # Load metadata from formatted object
        msiLoadMetadataFromXml(*geniXmlObjPath, *metadataObjPath);

        # Remove formatted metadata object
        msiDataObjUnlink(*metadataObjPath, *status);

        # Done
        writeLine("stdout", "Added metadata to "++*geniXmlObjPath);
}


dataObjExists(*objPath) {
        # Split path to get obj and coll names
        msiSplitPath(*objPath, *collection, *object);
        
        # Make query
        msiAddSelectFieldToGenQuery("DATA_ID", "count", *genQInp);
        msiAddConditionToGenQuery("DATA_NAME", "=", *object, *genQInp);
        msiAddConditionToGenQuery("COLL_NAME", "=", *collection, *genQInp);
        
        # Run query
        msiExecGenQuery(*genQInp, *genQOut);
        
        # Extract path from query result
        foreach (*genQOut) {
                msiGetValByKey(*genQOut, "DATA_ID", *count);
        }

        # Success?
        if (int(*count) > 0) {
                succeed;
        }
        else {
                fail(-310000);  #USER_FILE_DOES_NOT_EXIST
        }
}


hasExtension(*object,*extension) {
        # Get object extension
        *ext = triml(*object, ".");

        # Match?        
        if (*ext == *extension) {
                succeed;
        }
        else {
                fail(-815000);  #CAT_INVALID_DATA_TYPE
        }
}


INPUT *geniXmlObjPath=$1, *xsltObjPath="/pluto/home/rods/geni/geniObject.xsl"
OUTPUT ruleExecOut