GSAS/iRODSDescriptorProcessing: geni.re

acPostProcForPut { ON( ($objPath like "/geniRenci/home/public/md_tests/*") && ($oprType == 1) && 
                                                        (       ( $objPath like "*/Artifact1.xml" ) || 
                                                                ( $objPath like "*/Experiment1.xml" ) || 
                                                                ( $objPath like "*/Step1.xml" ) || 
                                                                ( $objPath like "*/project1.xml" ) || 
                                                                ( $objPath like "*/projectSerialized.xml" )     ))
                                                                
        {
                acGeniMetadataExtract();
        }
}       


acPostProcForCreate { ON( ($objPath like "/geniRenci/home/public/md_tests/*") &&
                                                        (       ( $objPath like "*/Artifact1.xml" ) || 
                                                                ( $objPath like "*/Experiment1.xml" ) || 
                                                                ( $objPath like "*/Step1.xml" ) || 
                                                                ( $objPath like "*/project1.xml" ) || 
                                                                ( $objPath like "*/projectSerialized.xml" )     ))
                                                                
        {
                # Flag object
                msiAddKeyVal(*KVP, "geni_md_xtract", "1");
                msiAssociateKeyValuePairsToObj(*KVP, $objPath, "-d");
        }
}       



acPostProcForOpen { ON( ($objPath like "/geniRenci/home/public/md_tests/*") &&
                                                        (       ( $objPath like "*/Artifact1.xml" ) || 
                                                                ( $objPath like "*/Experiment1.xml" ) || 
                                                                ( $objPath like "*/Step1.xml" ) || 
                                                                ( $objPath like "*/project1.xml" ) || 
                                                                ( $objPath like "*/projectSerialized.xml" )     ))
                                                                
        {
                # Check if object is flagged for metadata extraction
                if (hasFlag($dataId, "geni_md_xtract") >= 0) {
                        # Debug
                        #writeLine("serverLog","TEST:acPostProcForModifyDataObjMeta LOOKYHERE!!! "++$objPath); 
                        
                        # Remove flag
                        msiAddKeyVal(*KVP, "geni_md_xtract", "1");
                        msiRemoveKeyValuePairsFromObj(*KVP, $objPath, "-d");
                        
                        # Extract GENI metadata
                        acGeniMetadataExtract();
                }
        }
}                                                       
                                                                
                                                                
acGeniMetadataExtract() {
        *xsltObjPath="/geniRenci/home/public/md_tests/files/geniObject.xsl";
        *geniXmlObjPath=$objPath;
        
        # A few checks to get meaningful error messages
        dataObjExists(*geniXmlObjPath);
        dataObjExists(*xsltObjPath);
        hasExtension(*geniXmlObjPath,"xml");
        hasExtension(*xsltObjPath,"xsl");

        # Apply stylesheet
        msiXsltApply(*xsltObjPath, *geniXmlObjPath, *buffer);

        # Generate path of formatted metadata object
        msiSplitPath(*geniXmlObjPath, *collection, *filename);
        *metadataObjPath=*collection++"/"++trimr(*filename,".")++"_formatted.xml";

        # Create and write to metadata object
        msiDataObjCreate(*metadataObjPath, "forceFlag=", *D_FD);
        msiDataObjWrite(*D_FD, *buffer, *W_len);
        msiDataObjClose(*D_FD, *status);

        # Load metadata from formatted object
        msiLoadMetadataFromXml(*geniXmlObjPath, *metadataObjPath);

        # Remove formatted metadata object
        msiDataObjUnlink(*metadataObjPath, *status);

        # Done
        writeLine("serverLog", "[acGeniMetadataExtract] Added metadata to "++*geniXmlObjPath);

}


dataObjExists(*objPath) {
        # Split path to get obj and coll names
        msiSplitPath(*objPath, *collection, *object);
        
        # Make query
        msiAddSelectFieldToGenQuery("DATA_ID", "count", *genQInp);
        msiAddConditionToGenQuery("DATA_NAME", "=", *object, *genQInp);
        msiAddConditionToGenQuery("COLL_NAME", "=", *collection, *genQInp);
        
        # Run query
        msiExecGenQuery(*genQInp, *genQOut);
        
        # Extract path from query result
        foreach (*genQOut) {
                msiGetValByKey(*genQOut, "DATA_ID", *count);
        }

        # Success?
        if (int(*count) > 0) {
                succeed;
        }
        else {
                fail(-310000);  #USER_FILE_DOES_NOT_EXIST
        }
}


hasFlag(*dataID, *flag) {
        # Make query
        msiAddSelectFieldToGenQuery("META_DATA_ATTR_NAME", "count", *genQInp);
        
        msiAddConditionToGenQuery("META_DATA_ATTR_NAME", "=", *flag, *genQInp);
        msiAddConditionToGenQuery("META_DATA_ATTR_VALUE", "=", "1", *genQInp);
        
        msiAddConditionToGenQuery("DATA_ID", "=", *dataID, *genQInp);
        
        # Run query
        msiExecGenQuery(*genQInp, *genQOut);
        
        # Extract path from query result
        foreach (*genQOut) {
                msiGetValByKey(*genQOut, "META_DATA_ATTR_NAME", *count);
        }

        # Success?
        if (int(*count) > 0) {
                succeed;
        }
        else {
                fail(-808000);  #CAT_NO_ROWS_FOUND
        }
}


hasExtension(*object,*extension) {
        # Get object extension
        *ext = triml(*object, ".");

        # Match?        
        if (*ext == *extension) {
                succeed;
        }
        else {
                fail(-815000);  #CAT_INVALID_DATA_TYPE
        }
}